# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libspf2
pkgver=1.2.10
_debver=$pkgver
_debrel=7.1
pkgrel=1
pkgdesc="Sender Policy Framework record checking library"
arch=('i686' 'x86_64')
url='https://www.libspf2.org/'
license=('LGPL-2.1')
depends=('glibc' 'libnsl')
makedepends=('libmilter' 'quilt')
source=("https://www.libspf2.org/spf/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libs/libspf2/libspf2_${_debver}-${_debrel}~deb11u1.debian.tar.xz")
sha512sums=('162ce382628c6fcadac3e11f5a12442db622bb23f7ec503e16f5ba7fc88afdd777bce6b093c12a58210355985fd11b74b140f08fab347334d82d953dd183b130'
            'ce2ad5f3cf12ad7740fc84d51a3230e1f63ce7a3c937b73e6e8b7e4cc84b241a4afd99eec4c0fe62fad45612c4d30d29ff412e1543ec0c5b31ab06d7b7c3163f')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix='/usr'
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # remove unused binaries
  rm -v "${pkgdir}"/usr/bin/*_static "${pkgdir}/usr/bin/spfd" "${pkgdir}/usr/bin/spf_example" "${pkgdir}/usr/bin/spftest"

  # license
  install -Dm644 LICENSES -t "${pkgdir}/usr/share/licenses/$pkgname"
}