# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libsidplay
pkgver=1.36.60
_debver=1.36.60
_debrel=1
pkgrel=1
pkgdesc="A library for playing SID music files."
arch=('i686' 'x86_64')
url="https://critical.ch/distfiles/"
license=('GPL-2')
depends=('gcc-libs')
makedepends=('quilt')
source=(https://deb.debian.org/debian/pool/main/libs/libsidplay/libsidplay_$pkgver.orig.tar.bz2
        https://deb.debian.org/debian/pool/main/libs/libsidplay/libsidplay_$_debver-$_debrel.debian.tar.xz
        libsidplay-1.36.59-gcc43.patch
        g++-6_build.patch)
sha512sums=('51433057a910e99c6e888ad5f07c19721605565db6eb3ded7a13f90a4fe4e467f20e0b7ad15a4662d091bcaac3da4064d27dd7a73715b8012f1b1067cd3e38d6'
            '016ef548fd01031c5c6a5cbdbdad1f1d7947d57b25a727258a358229bce9a7d5e48e85493f723d733810530661b7451bd5e91eeaf56956112a588bc7101efb8d'
            '8ea90b2daffa1240729477f115bc57703c04bf4e44b7e1085b48a546d78886b61e514a5fc2d99906dca208baf364f8c4ba3e8f09774700ecd04ca47c7a8bea9e'
            'd7b2f77ef755b4c69eb05ba4292ba2371dcac4aa8f1a67819816031ab2ddc1e869677b9b40e0792921c009b8c7df1df508e2ba5a79c466565b40cc9fc33e2423')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  else
    patch -Np1 -i ../libsidplay-1.36.59-gcc43.patch
    patch -Np1 -i ../g++-6_build.patch
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}