# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=libretools
pkgname=(libretools librelib gitget xbs)
pkgdesc="Programs for Hyperbola development"
url="https://git.parabola.nu/packages/libretools.git/"
license=('GPL-3' 'GPL-2')

pkgver=20170505
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
        hyperbola.patch
        doas.patch
        gettext-tiny.patch
        remove-systemd_stdin_hack.patch)
sha512sums=('7034e12c6a3425b5c9eb05f2250397a5bb6ed89fda7129fcbc8ab2d56d6afa63dbd11c95dc0921cd087121b4c0168890136571a568b9fa89d9b4945a62cd3509'
            'SKIP'
            '5d702bf29ab9b0a607c6f45ec5641759150f2a3eb674bc55036bbac56dbd13e8f66fc2bda2ee4a722084e56b567861da092b364512ae30345fb0fa025a26abbd'
            '399866ab03c8cf923ff31aa71ae033d1732c5652fb67ff7c8882a786913361d3f0058f338bc726fa2d547c2ed4142999841e7886357cb4b46e5120342cbce241'
            '5e3b286c067bca460eab27915af9e98dbd6e9bd16e4cb0ccf7988870617f0d6b380d406519fad3ce13c45a3098e1a7f033ee14ad111abec16d614630479d86f7'
            '3d1223a3f8c2257de17c514eb0b68d32c188a42d332106a264be686e7735a2e2ec41cb062a0ec367dfb5846614983a0dc6c860a7d74dbc40e2d9ce146c284d1c')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

pkgrel=6
arch=('any')
makedepends=(ruby-ronn-ng gettext-tiny)
checkdepends=(sh-roundup git expac tokyocabinet)

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  patch -p1 -i ../hyperbola.patch
  patch -p1 -i ../doas.patch
  patch -p1 -i ../gettext-tiny.patch
  mv test/libredbdiff.d/statedir/pacman.arch{linux,}
  mv test/libredbdiff.d/statedir/pacman.{para,hyper}bola
  mv test/libredbdiff.d/statedir/pacman.hyperbola/sync/{libre,core}.db
  mv src/abslibre-tools/diff-{un,non}free
  sed -i '\|extra/devtools| s|devtools|libretools|' src/chroot-tools/arch-nspawn.in
  sed -i '\|CHROOT_VERSION|,+2 c echo "$CHROOT_VERSION" > "$working_dir/.arch-chroot"' src/chroot-tools/mkarchroot.in
  sed -i 's|/usr/bin/false|/bin/false|' test/librefetch-test.sh
  sed -i 's|/usr/bin/sed|/bin/sed|' src/librefetch/librefetchdir/{libmakepkg/source.sh.gen,makepkg.gen}
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make
}

check() {
  cd "$srcdir/$pkgbase-$pkgver"

  DOAS_USER= make check TESTENVFLAGS='--no-network --no-doas'
}

package_librelib() {
  pkgdesc="The shell library portion of libretools (adapted for Hyperbola)"
  license=(GPL-2)
  optdepends=(
    'libretools: for libreblacklist/blacklist.sh'
    'wget: for libreblacklist/blacklist.sh'
  )

  cd "$srcdir/$pkgbase-$pkgver"
  make install-librelib DESTDIR="$pkgdir"
  install -Dm644 COPYING-GPLv2 "$pkgdir/usr/share/licenses/$pkgname/COPYING-GPLv2"
}

package_gitget() {
  pkgdesc="A simple to use downloader for git URLs (adapted for Hyperbola)"
  license=(GPL-2)
  depends=("librelib=$pkgver" git)

  provides=("libregit=$pkgver")
  conflicts=("libregit")
  replaces=("libregit")

  cd "$srcdir/$pkgbase-$pkgver"
  make install-gitget DESTDIR="$pkgdir"
  install -Dm644 COPYING-GPLv2 "$pkgdir/usr/share/licenses/$pkgname/COPYING-GPLv2"
}

package_xbs() {
  pkgdesc='A tool for working with arbitrary ABS-like build systems (adapted for Hyperbola)'
  backup=(etc/xbs/xbs.conf
          etc/xbs/xbs-abs.conf)
  license=(GPL-2)
  depends=(
    "gitget=$pkgver" # `helper-abslibre`
    "librelib=$pkgver"
    subversion # `helper-abs`
  )

  cd "$srcdir/$pkgbase-$pkgver"
  make install-xbs DESTDIR="$pkgdir"
  install -Dm644 COPYING-GPLv2 "$pkgdir/usr/share/licenses/$pkgname/COPYING-GPLv2"
}

package_libretools() {
  backup=(etc/libretools.conf
          etc/libretools.d/chroot.conf
          etc/libretools.d/libredbdiff.conf
          etc/libretools.d/librefetch.conf)
  install=libretools.install
  conflicts=(devtools libretools-mips64el)
  replaces=(libretools-mips64el)

  depends=(
    "librelib=$pkgver"
    "xbs=$pkgver" # `createworkdir`, `librestage`
    'pacman>=5.0.1' 'pacman<5.1'
    arch-install-scripts # `mkarchroot` uses `pacstrap`
    expac # `libredbdiff`
    make # `librefetch`
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    chroot-nspawn # systemd-nspawn wrapper for chroot
    tokyocabinet # `toru`
    #namcap # Namcap is currently disabled in libremakepkg :-(
    #subversion # `diff-nonfree` # ignore because of xbs
    wget # `aur`, optdepend for librelib:`blacklist`
    opendoas # portable version of doas to run some commands as root
    binutils
  )

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
  for i in COPYING{,-GPLv2,-GPLv3}; do
    install -Dm644 $i "$pkgdir/usr/share/licenses/$pkgname/$i"
  done
}