# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libreplaygain
pkgver=475
_debver=475
_debrel=1
pkgrel=3
pkgdesc="A library to adjust audio gain"
arch=('i686' 'x86_64')
url="https://www.musepack.net/index.php?pg=src"
license=('LGPL-2.1')
depends=('glibc')
makedepends=('cmake' 'quilt')
source=("https://files.musepack.net/source/${pkgname}_r${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libr/libreplaygain/libreplaygain_1.0~r$_debver-$_debrel.debian.tar.gz"
        'LICENSE')
sha512sums=('b5fce8daf6aa8c8e0adb4c80089b43824b6503cb7d11e0c47c779c57a933b32f0c24722ca3fcf49711199fddcbb92c3fc13876f22418ca1521c7b8e27ba9d409'
            'eb293a29db2961a3715fb66d7388e5cbe01a201321fe18860a35a26fbe5d7bac6f3929dc18aed97cb53f45893cfa4706300aca11c5c4c278b3ebaed1f9c83f0a'
            '1bca76c9f2f559a7851c278650125cd4f44a7ae4a96ceee6a6ba81d34d28fe7d6125c5ee459fef729b6a2a0eba3075c0841c8a156b3a26f66194f77f7d49151c')

prepare() {
  cd ${pkgname}_r${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}"

  mkdir build
  cd build
  cmake ../${pkgname}_r${pkgver}/ \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "${srcdir}"/build

  make DESTDIR="${pkgdir}" install

  install -d "${pkgdir}"/usr/include/replaygain/
  install -Dm644 "${srcdir}"/${pkgname}_r${pkgver}/include/replaygain/* \
    "${pkgdir}"/usr/include/replaygain/

  install -Dm644 "${srcdir}"/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
}