# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libpgm
pkgver=5.3.128
_debver=$pkgver
_debrel=2
_pkgver="${pkgver//./-}"
pkgrel=2
pkgdesc="OpenPGM: implementation of the Pragmatic General Multicast (PGM, RFC3208)"
arch=('i686' 'x86_64')
url='https://www.freshports.org/net/openpgm/'
license=('LGPL-2.1')
depends=('glibc')
makedepends=('python' 'quilt')
options=(!strip)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/steve-o/openpgm/archive/release-${_pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libp/libpgm/libpgm_${_debver}~dfsg-${_debrel}.debian.tar.xz")
sha512sums=('ad1148cb01d982be48ca35c027938e60fc86f2da3de14e994c3d390a6c5b13385893f2bd87d23c2d6cbd9015770ff72ef6fb1090b6ccf3bfd0812189e67fd3bd'
            '72909c6418a3de568ecebce7f535aeab36a19904d169745eb0645036c4a46f254357c3f5c46bb7f5b149712474422da1c26736a4f81b1c2be85596d554e67346')

prepare() {
  cd "$srcdir/openpgm-release-$_pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd "$srcdir/openpgm-release-$_pkgver/openpgm/pgm"

  2to3 -wn version_generator.py
  # version 5.3.128 is a little broken
  cp openpgm-5.2.pc.in openpgm-5.3.pc.in
}

build() {
  cd "$srcdir/openpgm-release-$_pkgver/openpgm/pgm"
  ./bootstrap.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/openpgm-release-$_pkgver/openpgm/pgm"
  make prefix="$pkgdir/usr" install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}