# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libpaper
pkgver=1.1.28
pkgrel=1
pkgdesc='Library for handling paper characteristics'
arch=('i686' 'x86_64')
url='https://packages.debian.org/source/bullseye/libpaper'
license=('GPL-2')
depends=('sh' 'run-parts')
makedepends=('gettext-tiny')
backup=('etc/papersize')
source=("https://deb.debian.org/debian/pool/main/libp/libpaper/libpaper_$pkgver.tar.gz")
sha512sums=('3bf6ebb0af89931d2f72ea4a09a7fa958b2facda5f238983ec7bac39652e08614b33f0de3af74a03457b2a4203eee4950bf18a4b726e79aa64093ace6a1fb0bc')

prepare() {
  cd "$pkgname-$pkgver"
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # add systemwide default papersize read by many office applications
  install -dm 755 "$pkgdir"/etc
  echo '# Simply write the paper name. See papersize(5) for possible values' > "$pkgdir"/etc/papersize

  # add libpaper.d directory other packages can use to store files
  install -dm 755 "$pkgdir"/etc/libpaper.d

  # add localisation
  pushd debian/po
  for i in `ls *.po`; do
	install -dm 755 "${pkgdir}"/usr/share/locale/${i%.po}/LC_MESSAGES/;
	msgfmt $i -o "${pkgdir}"/usr/share/locale/${i%.po}/LC_MESSAGES/${pkgname}.mo;
  done
  popd

  # add license
  install -Dm 644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}