# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libotr
pkgver=4.1.1
_debver=4.1.1
_debrel=4
pkgrel=1
pkgdesc='Off-the-Record Messaging Library and Toolkit'
arch=('i686' 'x86_64')
url='https://otr.cypherpunks.ca/'
license=('GPL-2' 'LGPL-2.1')
depends=('libgcrypt')
makedepends=('quilt')
source=("https://otr.cypherpunks.ca/${pkgname}-${pkgver}.tar.gz"{,.asc}
        "https://deb.debian.org/debian/pool/main/libo/libotr/libotr_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c957206235b9f627542f23a645c822ea1b318d83fa655f41ed8d9a3c0dddf30b88f0ca82060026af155e48ecb13969dc9270831f20304669794151f666ae5cb0'
            'SKIP'
            '661e5ecafd010655fce7fdfc83738415b33c86f4ae8fcfa87dba5b232134ca4bf02239473099b2fb578ecb4f89b555ae760b71fcaf4173077605e479596d164e')
validpgpkeys=('22DF3305DF56667CE15784FCF24DE08F42C2ABAD') # OTR Dev Team


prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/0004-Suggest-pidgin-otr-to-Debian-and-Ubuntu-users-who-ha.patch || true

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}"
  for i in COPYING{,.LIB}; do
    install -m644 -v "$i" "${pkgdir}/usr/share/licenses/${pkgname}"
  done
}

# vim:set ts=2 sw=2 et: