# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libnfs
pkgver=4.0.0
_debver=4.0.0
_debrel=1
pkgrel=1
pkgdesc="client library for accessing NFS shares"
arch=('i686' 'x86_64')
url="https://github.com/sahlberg/libnfs"
license=('LGPL-2.1')
depends=('glibc')
makedepends=('quilt')
source=("https://github.com/sahlberg/$pkgname/archive/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libn/libnfs/libnfs_$_debver-$_debrel.debian.tar.xz")
sha512sums=('3d93d83d1909f24de304c0d47fa6240da7ecf43ce2488a242a58ddabe51d774caf813f5a90ae720a8edd251a765b30e88c0e5b6a13ecb254dfecdc98e30737fa'
            '4ba7c5dab818139ce2f108594b512f76c432d5faadd4290fe23665f3857b43517ca3f7da7c416ed8ec92ff0796ad2daa8f827bc876f148ef74e0ec2e6e3518bf')

prepare() {
	cd "$pkgname-$pkgname-$pkgver"

	if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
		# Debian patches
		export QUILT_PATCHES=debian/patches
		export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
		export QUILT_DIFF_ARGS='--no-timestamps'

		mv "$srcdir"/debian .

		quilt push -av
	fi

	autoreconf -vif
}

build() {
	cd "$pkgname-$pkgname-$pkgver"

	./configure --prefix=/usr
	make
}

package() {
	cd "$pkgname-$pkgname-$pkgver"

	make DESTDIR="$pkgdir" install

	install -Dm644 LICENCE-LGPL-2.1.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}