# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libnewt
pkgver=0.52.21
_debver=$pkgver
_debrel=4
pkgrel=1
_tclver=8.6
pkgdesc="Not Erik's Windowing Toolkit - text mode windowing with slang"
arch=('i686' 'x86_64')
url='https://pagure.io/newt'
license=('LGPL-2')
depends=('gpm' 'libxcrypt' 'popt' 'slang')
makedepends=('python' "tcl>=$_tclver" 'quilt')
optdepends=('python: libnewt support with the _snack module'
            'tcl: whiptcl support')
options=(!makeflags)
source=("https://releases.pagure.org/newt/newt-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/newt/newt_$_debver-$_debrel.debian.tar.xz")
sha512sums=('d53d927996d17223e688bf54dccfabb2a3dc02bfe38ffc455964e86feaca3cd9f9ab5b19774433be430fa4d761cd9b6680b558f297acb86f80daeb6942f7d23c'
            'c980721e4f725e945ff5cf255674d3cbd7e090709e70c93a341311209aedf2f7b7f9b49d1146371020c90a3805fc3bb2a49ab3b52ef233245c496721ae3b3151')

prepare() {
  cd newt-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  echo '#define USE_INTERP_RESULT 1' >> config.h
  sed -i "s:tcl8.4:tcl$_tclver:" Makefile.in
}

build() {
  cd newt-$pkgver
  ./configure --prefix=/usr --with-gpm-support
  make
}

package() {
  make -C newt-$pkgver prefix="$pkgdir/usr" install
  install -Dm644 newt-$pkgver/COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}