# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libmms
pkgver=0.6.4
_debver=0.6.4
_debrel=3
pkgrel=2
pkgdesc="MMS stream protocol library"
arch=(i686 x86_64)
url="https://sourceforge.net/projects/libmms/"
license=(LGPL-2.1)
depends=('glibc')
makedepends=('quilt')
source=(https://download.sourceforge.net/libmms/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/libm/libmms/libmms_$_debver-$_debrel.debian.tar.xz)
sha512sums=('9771c697515f5232eaeaff79e68fe15e34d8aa38aa5d3d68525216357223f314c544d71b5fe18d79a77682f41b1b5d9fb5e7c3c99d0cba5723d2e3de31faec96'
            'd6da31229d629ea6c9119a464fa8b6cc1c012539f469c2176f486743463af08f54e05985a02e0b0cdd01bde0f652567166470e348f8684b60b93e002c4c63814')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.LIB -t "${pkgdir}/usr/share/licenses/${pkgname}"
}