# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=liblrdf
pkgver=0.6.1
_debver=$pkgver
_debrel=4
pkgrel=2
pkgdesc="A library for the manipulation of RDF file in LADSPA plugins"
arch=('i686' 'x86_64')
url="https://github.com/swh/LRDF"
depends=('raptor')
makedepends=('ladspa' 'quilt')
license=('GPL-2')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/swh/LRDF/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libl/liblrdf/liblrdf_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('7732813eec704aef984d056de254e4fa049fdd0a7444b6a88f75f012afe9c587cbd1295f027c77361fa42bc097cdce9d9cabdba6b86e99a3c14805d84258df1c'
            'ede6a55862b248cdf886fa1ba4e776772ada916a368f497493f25e11782a8c5b1641de2719f407161bafe125dbf377f61ba6ba79f619c3076b7aad04dc18ee58')

prepare() {
  mv -v "LRDF-${pkgver}" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  # raptor.h changed location
  export CXXFLAGS="$(pkg-config --cflags raptor2) ${CXXFLAGS}"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,README} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}