# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libisoburn
pkgver=1.5.2 #.pl01
_debver=1.5.2
_debrel=1
pkgrel=1
pkgdesc="frontend for libraries libburn and libisofs"
url="https://dev.lovelyhq.com/libburnia"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('libburn' 'libisofs' 'readline')
makedepends=('quilt')
optdepends=('tk: for xorriso-tcltk frontend')
provides=('xorriso' 'xorriso-tcltk' 'cdrkit' 'cdrtools' 'dvdrtools')
conflicts=('cdrkit''cdrtools' 'dvdrtools')
replaces=('cdrkit' 'cdrtools' 'dvdrtools')
source=(https://files.libburnia-project.org/releases/${pkgname}-${pkgver}.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/libi/libisoburn/libisoburn_$_debver-$_debrel.debian.tar.xz)
sha512sums=('b481aa5ff20bb35ab0ab19f3f4f3ebc4f2baa8366a14a5afe4f262788441679b6501e140e182f4e80045c747f1cf48db40832d8d5cd064e58a02de2882536897'
            'SKIP'
            '9b5264104f219c9f95ae640e8fd45274ab90298724fd3ced1efa35e9c0466c0ec6fb623fce05158310250baa15282e090a9e690ae132d65415cb4d2ec219cb80')
validpgpkeys=('44BC9FD0D688EB007C4DD029E9CBDFC0ABC0A854') # Thomas Schmitt <scdbackup@gmx.net>

prepare() {
  cd ${pkgname}-${pkgver/.pl01/}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/01-switch-to-libjte2.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver/.pl01/}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver/.pl01/}
  make DESTDIR=${pkgdir} install

  for i in COPYING COPYRIGHT; do
    install -Dm644 ${i} ${pkgdir}/usr/share/licenses/${pkgname}/${i}
  done

  # Make symlinks for cdrkit/cdrtools/dvdrtools compatibility
  install -dm755 $pkgdir/usr/share/man/man8/

  ln -s xorrisofs $pkgdir/usr/bin/genisoimage
  ln -s xorrisofs $pkgdir/usr/bin/mkhybrid
  ln -s xorrisofs $pkgdir/usr/bin/mkisofs

  ln -s xorrisofs.1.gz $pkgdir/usr/share/man/man1/genisoimage.1.gz
  ln -s xorrisofs.1.gz $pkgdir/usr/share/man/man1/mkhybrid.1.gz
  ln -s xorrisofs.1.gz $pkgdir/usr/share/man/man8/mkhybrid.8.gz
  ln -s xorrisofs.1.gz $pkgdir/usr/share/man/man1/mkisofs.1.gz
  ln -s xorrisofs.1.gz $pkgdir/usr/share/man/man8/mkisofs.8.gz
}