# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libircclient
pkgver=1.9
_debver=1.9
_debrel=1
pkgrel=1
pkgdesc='Small but powerful library, which implements client-server IRC protocol'
arch=('i686' 'x86_64')
url='https://www.ulduzsoft.com/linux/libircclient/'
license=('GPL-2')
depends=('libressl')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libi/libircclient/libircclient_$_debver-$_debrel.debian.tar.xz")
sha512sums=('6f424791fed94ecacdd5d0b2c04472b0ddba09da08a8efb76c115a2a6abedecdf0aab3a86632bdf0fbca78781256fb591d8c94ed8eb776c5f30557d5c426bd1c'
            '89f777915523ce41ddbd85ea9c859131544eafee3e45c635ffc440b60d079389de303e4bb55308fb59bef9be69a2a2b24351564992641f773129ba5ba41f9de1')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/proper-lib-building.patch || true

    quilt push -av
  fi

  # fix include dir path
  sed -i "s/@\/include/&\/${pkgname}/" src/Makefile.in

  # support openssl 1.1
  sed -e 's|SSL_library_init|OPENSSL_init_ssl|' -i configure.in

  autoreconf -vi
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr \
              --libdir=/usr/lib \
              --enable-shared \
              --enable-openssl \
              --enable-ipv6
  make -C src
}

package() {
  cd $pkgname-$pkgver

  make -C src DESTDIR="${pkgdir}" install

  # examples
  install -t "${pkgdir}/usr/share/${pkgname}/examples" -Dm644 ./examples/*

  # license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}