# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libidn
pkgver=1.33
_debver=1.33
_debrel=2.4
pkgrel=2
pkgdesc="Implementation of the Stringprep, Punycode and IDNA specifications"
url="https://www.gnu.org/software/libidn/"
arch=('i686' 'x86_64')
license=('LGPL-3')
depends=('glibc')
makedepends=('help2man' 'texinfo' 'automake=1.14' 'quilt')
source=("https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/libi/libidn/libidn_$_debver-$_debrel.debian.tar.xz")
sha512sums=('38dd459eaeda0c9e3cc2d24d967113515a499747550a2a9157f32357def90d71a3a3b52398e96a44a28cd5948dc353b0473c4ff0453a69720191c4cb49cac2c6'
            'SKIP'
            'fb98761e99a05a9ca42b05e06fa8f89d3116cdbdddb7c2f1697ae1439318e6a2face3221c13ba08e95c3a5db9ed81f3491e53bafe11ba03492649d07d91ba0c3')
validpgpkeys=('9AA9BDB11BB1B99A21285A330664A76954265E8C') # "Simon Josefsson <simon@josefsson.org>"

prepare() {
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .
    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --disable-gtk-doc
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}
package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
  install -dm755 ${pkgdir}/lib
  mv ${pkgdir}/usr/lib/libidn.so.11* ${pkgdir}/lib
  ln -sf ../../lib/libidn.so.11 ${pkgdir}/usr/lib/libidn.so
  install -d -m755 ${pkgdir}/usr/share/licenses/${pkgname}
  install -m644 COPYING{,.LESSERv3} ${pkgdir}/usr/share/licenses/${pkgname}
}