# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libetpan
pkgver=1.9.4
_debver=1.9.4
_debrel=3
pkgrel=1
pkgdesc='A portable middleware for email access'
arch=('i686' 'x86_64')
url='https://www.etpan.org/libetpan.html'
license=('Modified-BSD')
depends=('libgcrypt' 'gnutls' 'libsasl' 'zlib')
makedepends=('expat' 'quilt')
source=($pkgname-$pkgver.tar.gz::https://github.com/dinhviethoa/${pkgname}/archive/${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/libe/libetpan/libetpan_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('7b7047d084fb4ce0c91821c2ad78e921d6d009106851afb7f5b068713c84ebe6926f6bf7a7423f263eeebef617511e44f6b65448d892bbc058c447235fd55c0f'
            'bf592cbb27518d5e62d1b45de2be7398a1aea279522b1eb3bba2efb46cfada8c2f6329d1c3cd3424b40c68d935fc9f15fc52c31236bf4409ba28eba1f3edd8b1')

prepare() {
  cd "${pkgname}"-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/11_use_openjade.diff || true

    quilt push -av
  fi

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd "${pkgname}"-${pkgver}

  ./configure --prefix=/usr \
    --disable-static \
    --disable-db \
    --with-openssl=no \
    --with-gnutls=yes
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${pkgname}"-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYRIGHT -t "${pkgdir}"/usr/share/licenses/$pkgname
}