# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libdom
pkgver=0.4.1
pkgrel=1
pkgdesc='Implementation of the W3C DOM'
arch=('i686' 'x86_64')
url='https://www.netsurf-browser.org/projects/libdom/'
license=('Expat')
depends=('expat' 'libhubbub>=0.3.7' 'libwapcaplet>=0.4.3')
makedepends=('netsurf-buildsystem')
source=("https://download.netsurf-browser.org/libs/releases/$pkgname-$pkgver-src.tar.gz")
sha512sums=('8927b294c98dcb424a454036b20981963ba9982c1aad95b07fc0ca1efc58756b7d85373ed4cde0dcff6281b518a2b5993358494f432d85f7ac7ebd51230a6c22')

prepare() {
  sed -i 's:_BSD_SOURCE:_DEFAULT_SOURCE:' "$pkgname-$pkgver/Makefile"
}

build() {
  export CFLAGS="$CFLAGS -shared -fPIC -w"
  export LDFLAGS="$LDFLAGS -shared -z,now"
  make -C "$pkgname-$pkgver" \
    INCLUDEDIR=include \
    LIBDIR=lib \
    PREFIX=/usr \
    COMPONENT_TYPE="lib-shared"
}

package() {
  make -C "$pkgname-$pkgver" \
    DESTDIR="$pkgdir" \
    INCLUDEDIR=include \
    LIBDIR=lib \
    PREFIX=/usr \
    COMPONENT_TYPE="lib-shared" \
    install

  install -Dm644 "$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
}