# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libb2
pkgver=0.98.1
_debver=$pkgver
_debrel=1.1
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Free and libre C library providing BLAKE2b, BLAKE2s, BLAKE2bp, BLAKE2sp hash functions"
url='https://blake2.net/'
license=('CC0-1.0')
depends=('gcc-libs')
makedepends=('quilt')
source=("https://github.com/BLAKE2/libb2/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libb/libb2/libb2_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('e760972173bb9ff3562843882abbe9042af09da63f37a5706921381be2d64cc4d333aec65e1e676d5a45ace913417536a1dc188c90b394c2f7b9cae654dbb108'
            'dcc35643ae61e8e932bf5bee0031b554c316108283d4e1b4b63a53ea28eb88288f657073ca117cf9961b0fb12ed5919e837889956017e3549a794272c9cff63f')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-shared \
    --disable-native \
    --enable-fat
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}