# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lesstif
pkgver=0.95.2
pkgrel=1
pkgdesc="Free and libre implementation of Motif"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/lesstif/'
license=('LGPL-2')
depends=('freetype2' 'libxt' 'libxp')
options=('!makeflags' '!buildflags')
conflicts=('openmotif')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        "property-64bit.diff")
sha512sums=('228c032e00998f774af4677e8af442b6d29eb0781a6cea27ad200fe2d89997dea8326df75000befbd976007c92a886b043a13cefda2b772d4ac7a9958dc58e99'
            '59ca8af545a6b74cf54b03a21dc5b63b5e4fbe3e0a992f603eeb9094c84b59a295bdfc74d2fc20fa548da97802b7170e19d49bc674c5620e39984fa1ad1badd6')

prepare() {
  cd ${pkgname}-${pkgver}

  patch -p1 -i "${srcdir}"/property-64bit.diff
}

build() {
  cd ${pkgname}-${pkgver}

  CFLAGS="$CFLAGS -L${srcdir}/${pkgname}-${pkgver}/lib/Xm-2.1/.libs"
  ./configure --prefix=/usr \
    --enable-production \
    --enable-nonstandard-conversions \
    --enable-editres \
    --with-xdnd \
    --enable-build-21 \
    --disable-debug

  # fix linkage against already installed version
  perl -pi -e 's/^(hardcode_into_libs)=.*/$1=no/' libtool

  make

  # fix linkage against already installed version
  for f in $(find . -name \*.la -type f) ; do
    perl -pi -e 's/^(relink_command=.*)/# $1/' $f
  done

  make -C lib/Mrm-2.1
}

package() {
  cd ${pkgname}-${pkgver}

  make -C lib/Mrm-2.1 DESTDIR="${pkgdir}" install
  make DESTDIR="${pkgdir}" appdir=/usr/share/X11/app-defaults rootdir=/usr/share/doc/LessTif install
  install -Dm644 COPYING.LIB -t "${pkgdir}"/usr/share/licenses/${pkgname}
}