# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lensfun
pkgver=0.3.2
pkgrel=1
_debver=0.3.2
_debrel=6
pkgdesc='Database of photographic lenses and a library that allows advanced access to the database'
arch=(i686 x86_64)
url='https://lensfun.github.io/'
license=(GPL-3 LGPL-3 CC-BY-SA-3.0) # software, libraries and database
depends=(glib2) # libpng is only required for lenstools build
optdepends=('python: for lensfun-update-data and lensfun-add-adapter')
makedepends=(cmake doxygen python-docutils quilt)
source=($pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/refs/tags/v$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/l/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz
        COPYING.CC_BY-SA_3.0::https://creativecommons.org/licenses/by-sa/3.0/legalcode.txt)
sha512sums=('9c6f546fa70e6dc692e66ef378447345be6d3383812934780d326d772d775c1918cbf3447cd91c067655044cf659025763bf47ba2d938a82a3c2de4d60127446'
            '62fa1d853b90480a4788549be02b63872c3bd8ce8c43542f29bcf66b0729d48caf7db5729203387327866c17abd508872aea25e1d8493e3dd9eb635bddca1130'
            '2635a3dd63d647420f31346be165fe0481f9606b1676653b1201f7725e61c25c2daead810e12c3358724e24dd6b09327cd33a0ec93b3c0d47a629138e12c45e6')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  cmake . \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_DOC=OFF \
    -DBUILD_FOR_SSE=ON \
    -DBUILD_FOR_SSE2=ON \
    -DBUILD_LENSTOOL=OFF # disabled, due Makefile2 error
  make -v all
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -Dm644 docs/gpl-3.0.txt -t $pkgdir/usr/share/licenses/$pkgname
  install -Dm644 docs/lgpl-3.0.txt -t $pkgdir/usr/share/licenses/$pkgname
  install -Dm644 ../COPYING.CC_BY-SA_3.0 -t $pkgdir/usr/share/licenses/$pkgname
}

# vim:set sw=2 et: