# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lame
pkgver=3.100
_debver=3.100
_debrel=3
pkgrel=1
pkgdesc='A high quality MPEG Audio Layer III (MP3) encoder'
arch=('i686' 'x86_64')
url='http://lame.sourceforge.net/'
depends=('ncurses')
makedepends=('nasm' 'quilt')
license=('LGPL-2')
source=("https://downloads.sourceforge.net/lame/lame-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/l/lame/lame_$_debver-$_debrel.debian.tar.xz")
sha512sums=('0844b9eadb4aacf8000444621451277de365041cc1d97b7f7a589da0b7a23899310afd4e4d81114b9912aa97832621d20588034715573d417b2923948c08634b'
            'f7beaf4a2da51e6f5940c26986621a57094236c62c12df1d36d6ef08a6c129276f253bec50a5bbfb176de87466a3615ffdebf79c507a57dd598ad9978fd8784d')

prepare() {
  cd lame-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/patches debian

    # Doesn't apply and seems unimportant
    rm -v debian/patches/msse.patch || true

    quilt push -av
  fi
}

build() {
  cd lame-${pkgver}

  ./configure \
    --prefix='/usr' \
    --enable-nasm \
    --enable-shared
  make
}

package() {
  cd lame-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}
# vim: ts=2 sw=2 et: