# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kyotocabinet
pkgver=1.2.76
_debver=$pkgver
_debrel=4.2
pkgrel=1
pkgdesc="A modern implementation of DBM in C++"
arch=('i686' 'x86_64')
url='http://fallabs.com/kyotocabinet/'
license=('LGPL-3')
depends=('zlib' 'lzo' 'xz' 'gcc-libs')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/k/kyotocabinet/kyotocabinet_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/k/kyotocabinet/kyotocabinet_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('278db7b327eb4c21bf0137d9aa14fb67d74d5ce7ed1cb29fc9120d157a60de165ec0cf842903eb7952e8f998045ae585b958977fa973ba0e0773381de71d9f6a'
            '1351b38d6e65b6825043d72f9c23dde086d3a0b391753390234eeb6e9b061181805494d8da2e97cd818c1e70f4a86ea5f72f3854dc4778ef24aef2d535405943')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/kfreebsd-support-getsysinfo-on-GNU-kFreeBSD.patch || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-zlib \
    --enable-lzo \
    --enable-lzma \
    --disable-opt
  make
}

package() {
  cd $pkgname-$pkgver
  make install DESTDIR="$pkgdir/"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}