# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kobodeluxe
pkgver=0.5.1
_debver=0.5.1
_debrel=10
pkgrel=1
pkgdesc="An enhanced version of Akira Higuchi's game XKobo, an addictive space shoot'em up"
arch=('i686' 'x86_64')
url="http://www.olofson.net/kobodl/"
license=('GPL-2' 'LGPL-2.1')
depends=('sdl_image' 'hicolor-icon-theme')
makedepends=('quilt')
groups=('games')
install=kobodeluxe.install
source=(https://deb.debian.org/debian/pool/main/k/kobodeluxe/kobodeluxe_${pkgver}.orig.tar.gz
        https://deb.debian.org/debian/pool/main/k/kobodeluxe/kobodeluxe_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('01bd3ed84fa9d1a63a748a2e8cade9e0574bf73e289fa438711d7747d99d8dd29283be23ff18da9a6e5115b8e89ee6e4d283ccc97728eddcff5d70ced2f9fb52'
            '11c166464d547cd0d65d9e41c4a83e9538e5d08b6448909b89d7047e06b21050ecde711e02c22dea00cc237ce43be4340ee2829b215ae61a4b55d7d1f83e0323')

prepare() {
  cd KoboDeluxe-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  tar -xf icons.tar.gz
}

build() {
  cd KoboDeluxe-${pkgver}
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games \
    --localstatedir=/var \
    --sharedstatedir=/var/games
  make
}

package() {
  cd KoboDeluxe-${pkgver}
  make DESTDIR="${pkgdir}" install

  install -D -m644 icons/KDE/kobo-deluxe.desktop "${pkgdir}/usr/share/applications/kobo-deluxe.desktop"
  for i in 16 22 32 48 64 128 ; do
    install -D -m644 icons/KDE/icons/${i}x${i}/kobodl.png "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/kobodl.png"
  done

  chown root:games "${pkgdir}/usr/games/kobodl"
  chmod 2755 "${pkgdir}/usr/games/kobodl"
  chown root:games "${pkgdir}/usr/share/games/kobo-deluxe"
  chmod 2755 "${pkgdir}/usr/share/games/kobo-deluxe"
  chown root:games "${pkgdir}/var/games"
  chmod 775 "${pkgdir}/var/games"
  chown root:games "${pkgdir}/var/games/kobo-deluxe"
  chmod 775 "${pkgdir}/var/games/kobo-deluxe"
  chown root:games "${pkgdir}/var/games/kobo-deluxe/scores"
  chmod 775 "${pkgdir}/var/games/kobo-deluxe/scores"

  install -Dm644 {COPYING,COPYING.LIB} -t "$pkgdir/usr/share/licenses/$pkgname"
}