# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=khtml
pkgver=5.33.0
pkgrel=1.hyperbola1
pkgdesc='KHTML APIs, without Java support'
arch=('i686' 'x86_64')
url='https://community.kde.org/Frameworks'
license=('GPL-3' 'LGPL-2.1')
depends=('giflib' 'kparts' 'kjs')
makedepends=('extra-cmake-modules' 'python')
groups=('kf5-aids')
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/portingAids/${pkgname}-${pkgver}.tar.xz"{,.sig}
        'remove-java-support.patch')
sha512sums=('6d380ad8276772f8851334b593d1545453a039cd5de6b2ab2a4f76dbfa2942d4763c01781aec51a1dd5fb73646332594660efb732cab3d6149c1339f884fc443'
            'SKIP'
            '55f6b2086592a038e2725e961cde5272ec3ca933d317d413d53b9261c0b0c1708da226e84862fbff61bd3301a79fd6328cf9b385c53f67b6f9b41c8cd8e4b7a5')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build
  cd ${pkgname}-${pkgver}
  patch -p1 -i ../remove-java-support.patch
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  for i in COPYING.{GPL3,LIB}; do
    install -Dm644 ../${pkgname}-${pkgver}/${i} ${pkgdir}/usr/share/licenses/${pkgname}/${i}
  done
}