# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=khotkeys
pkgver=5.9.5
pkgrel=1.hyperbola2
pkgdesc='KHotKeys, with searx support'
arch=('i686' 'x86_64')
url='https://www.kde.org/workspaces/plasmadesktop/'
license=('GPL-2' 'LGPL-2.1')
depends=('plasma-workspace')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'kdesignerplugin')
conflicts=('kdebase-workspace')
groups=(plasma)
source=("https://download.kde.org/stable/plasma/${pkgver}/$pkgname-$pkgver.tar.xz"{,.sig})
sha512sums=('5e0fb509cbd799af6dd720e03c691c23a056e944cd26166a14c45d033312eb46d2bf78ad7ab28658f8a866dfd7b45369c05f5572a72590b75da8da04bb337f5c'
            'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '348C8651206633FD983A8FC4DEACEA00075E1D76'  # KDE Neon
              'D07BD8662C56CB291B316EB2F5675605C74E02CF') # David Edmundson

prepare() {
  mkdir -p build
  cd ${pkgname}-${pkgver}
  sed -i 's|http[:][/][/]google[.]com|https://searx.openpandora.org|' data/defaults.khotkeys
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  for i in COPYING{,.LIB}; do
    install -Dm644 ../${pkgname}-${pkgver}/${i} ${pkgdir}/usr/share/licenses/${pkgname}/${i}
  done
}