# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kcoreaddons
pkgver=5.78.0
pkgrel=2
_debver=$pkgver
_debrel=4
pkgdesc='Addons to QtCore'
arch=(i686 x86_64)
url='https://community.kde.org/Frameworks'
license=('custom:LGPL-3+Qt-Exception-1.1')
depends=(qt-base)
optdepends=('python-pyqt: for the Python bindings')
makedepends=(doxygen extra-cmake-modules graphviz python-pyqt qt-tools sip)
groups=(kf5)
source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig}
        https://deb.debian.org/debian/pool/main/${pkgname::1}/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('0056c993a741a5bc24973f30c578c9b601884aff6c22da21a135c84218a5f796021cba8eb1fecf13428d4e98c97b4e6f1646839c7de62b5f667e579effb726e8'
            'SKIP'
            'a9539fb16dd79edeadd33b5c7a48b8258f6e22b7b0f82238ed56ab55edf5352391f935406556ee9d7a829bbd27f5d47a0082def2487b35093301e1609fd5a3bd')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -D_KDE4_DEFAULT_HOME_POSTFIX=4 \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install

  install -Dm644 $pkgname-$pkgver/LICENSES/LicenseRef-KDE-Accepted-LGPL.txt -t $pkgdir/usr/share/licenses/$pkgname
  install -Dm644 $pkgname-$pkgver/LICENSES/Qt-LGPL-exception-1.1.txt -t $pkgdir/usr/share/licenses/$pkgname
}