# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kconfig
pkgver=5.78.0
_pkgver=5.78
pkgrel=2
_debver=$pkgver
_debrel=4
pkgdesc='KF5 Configuration system'
arch=(i686 x86_64)
url='https://community.kde.org/Frameworks'
license=(LGPL-3)
depends=(qt-base)
makedepends=(doxygen extra-cmake-modules python-pyqt qt-tools quilt sip)
optdepends=('python-pyqt: for the Python bindings')
groups=(kf5)
source=(https://download.kde.org/Attic/frameworks/$_pkgver/$pkgname-$pkgver.tar.xz{,.sig}
        https://deb.debian.org/debian/pool/main/k/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('cb2f34c5d0e7683629d1cbe7a8dd7b5ebd52d2638bb05ca5c4869173b681f60f468fb94a0f9ef9b27d0eb02d9586f2af3d7939ebcb4fe17d8b11ed7f5a31a8b5'
            'SKIP'
            '70602d7021d441080626d748e9c17a62a039a51ed681ac509e16551bb37f4b9f317a3094cac82bfcce056a71eb68188ffcbbcadd38857a3ded6ab19a3aceab20')
validpgpkeys=('53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB') # David Faure <faure@kde.org>

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D KCONFIG_USE_DBUS=OFF \
    -D BUILD_TESTING=OFF \
    -D BUILD_QCH=ON
  make -C build
}

package() {
  make DESTDIR=$pkgdir -C build install

  install -Dm644 $pkgname-$pkgver/LICENSES/LicenseRef-KDE-Accepted-LGPL.txt -t $pkgdir/usr/share/licenses/$pkgname
}