# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=kcompletion
pkgver=5.78.0
pkgrel=2
_debver=$pkgver
_debrel=3
pkgdesc='Text completion helpers and widgets'
arch=(i686 x86_64)
url='https://community.kde.org/Frameworks'
license=(LGPL-2.1)
depends=(kwidgetsaddons kconfig)
optdepends=('python-pyqt: for the Python bindings')
makedepends=(doxygen extra-cmake-modules graphviz python-pyqt qt-tools sip)
groups=(kf5)
source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig}
        https://deb.debian.org/debian/pool/main/${pkgname::1}/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('29fbc9c56a34601a4c674c45d04a3d2b79beebe0484c2dc80bf7a9a71de9c8ee82b548bd8d3df521593a60e37f0789d9e23eec5058fab9c3bfee2e53c8d6f58a'
            'SKIP'
            'd551deb098c8e0ea3d133249bd1661786aa1f0e091b037dcbf4b3645440569f59855ddd418c679a2f9744d27a1e3a2c2321ec1b95e1e55bb43186f5504584534')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install

  install -Dm644 $pkgname-$pkgver/LICENSES/LGPL-2.1-or-later.txt -t $pkgdir/usr/share/licenses/$pkgname
}