# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=joe
pkgver=4.6
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="User friendly, free and libre full screen text editor"
arch=('i686' 'x86_64')
url='https://joe-editor.sourceforge.io/'
license=('GPL-2')
depends=('ncurses')
makedepends=('quilt')
optdepends=('gpm: console mouse support')
backup=('etc/joe/ftyperc'
        'etc/joe/jicerc.ru'
        'etc/joe/jmacsrc'
        'etc/joe/joerc'
        'etc/joe/jpicorc'
        'etc/joe/jstarrc'
        'etc/joe/rjoerc')
source=("https://downloads.sourceforge.net/joe-editor/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/j/joe/joe_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('3dd64a994fb3d352a12bf027ef16d57d14ac2577fd63fb6b6e25cae46052befaa7c15dc029bff2f8c3275df90f0343bd46313601055d97277ea4540e109fbe82'
            '2a3d35db604de33291a935da538ab885317d03a1c773cc866c532425c241e66a6c6d4e6b6c4524683ddbe823b0a31c9c5dcc3b1998d4a7ae9c6f8fb6dee0a204')

prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/004_debcontrol_syntax.patch || true

    quilt push -av
  fi
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --mandir=/usr/share/man
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}/" install
  rm "${pkgdir}"/usr/share/${pkgname}/syntax/{ant,avr,csharp,debian,dockerfile,groovy,haskell,iptables,java,pascal,php,powershell,r,rust,typescript}.jsf
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}