# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=isomaster
pkgver=1.3.13
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Graphical CD image editor"
arch=('i686' 'x86_64')
url='http://littlesvr.ca/isomaster'
license=('GPL-2')
depends=('gtk2' 'desktop-file-utils')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.bz2::https://deb.debian.org/debian/pool/main/i/isomaster/isomaster_${pkgver}.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/i/isomaster/isomaster_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('dbc6a77fabf8d454bbde25a7540e68820bf773bc991176e5684e87aeb6044ad1bbbcf1c4f537148c18ec8847572949a52d6578a14f68b8ad3f21d542685859ba'
            '32a237e676fc55f45e5ad358f6f94138dff5581d761f36627f3e2a323ddbe4e72c7736ed840dea7b207a3c95be382f3d7d6dbf705b063a4cbdb910ecc14de7af')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  sed -i 's/m 644/Dm 644/' Makefile
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  for n in ./po/*.po; do
    msgfmt $n -o ./po/`basename $n .po`.mo
  done
  make PREFIX=/usr
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  install -d ${pkgdir}/usr/share/locale
  for n in ./po/*.mo; do
    install -p -D -m644 $n ${pkgdir}/usr/share/locale/`basename $n .mo`/LC_MESSAGES/${pkgname}.mo
  done
  make PREFIX=/usr DESTDIR="${pkgdir}" install
  install -Dm644 LICENCE.TXT -t "${pkgdir}/usr/share/licenses/${pkgname}"
}