# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ijs
pkgver=0.35
_debver=$pkgver
_debrel=15
pkgrel=4
pkgdesc="A library which implements a protocol for transmission of raster page images"
arch=('i686' 'x86_64')
url='https://www.openprinting.org/download/ijs/'
license=('Expat' 'GPL-2')
depends=('glibc' 'sh')
makedepends=('ghostscript' 'quilt')
source=("https://www.openprinting.org/download/ijs/download/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/i/ijs/ijs_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('b5f8df6fe394efea4ee7059c1ca8d7eb91588f060642da12f6591f0f40d169883aa9f7a6976a00042c89dd370b30f36afc407c4e7515cbd68537505a63c9a293'
            'dca54da109d9c6b0deaddc60d8224f8626339be8c07ee14f6968ea763a79e44ab10a14bbd43ad43304a071f2396df927bc4f5b3bd7f0c08fe00f856733161cdb')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/020160121~0c176a9.patch || true
    rm -v debian/patches/1002_use_db2pdf.patch || true

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-shared \
    --mandir=/usr/share/man
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install

  # install doc
  install -Dm644 ijs_spec.pdf ${pkgdir}/usr/share/doc/$pkgname/ijs_spec.pdf

  # install license
  install -Dm644 debian/copyright -t ${pkgdir}/usr/share/licenses/$pkgname
}