# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=id3v2
pkgver=0.1.12
_debver=$pkgver
_debrel=7
pkgrel=1
pkgdesc="Utility to edit id3v2 tags"
arch=('i686' 'x86_64')
url='http://id3v2.sourceforge.net/'
license=('LGPL-2.1')
depends=('gcc-libs' 'glibc' 'id3lib' 'zlib')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/i/id3v2/id3v2_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('f9c74ab6ffbb50ab7ae7af64dcde78a0766bcbf71308d4c9fb480543b5790e2690ae096d6a2ecaffb01b7497a18841b5235500177cf5eaa8e668cf443abc726a'
            '39d2bf0bb71e02b6b176c495965c38fe828447e40196d60331dcfe85830d8dc131472a0a1da108953e0bed9eab1c42c87bc217cedda324634525ab89d3e57c80')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make clean
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  install -d -m755 "${pkgdir}"/usr/{bin,share/man/man1}
  make PREFIX="${pkgdir}/usr" install
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
}