# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=id3
pkgver=1.1.2
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Utility to edit id3-tags"
arch=('i686' 'x86_64')
url='https://devel.ringlet.net/audio/id3/'
license=('GPL-2')
depends=('gcc-libs')
makedepends=('quilt')
options=('!makeflags')
source=("https://deb.debian.org/debian/pool/main/i/id3/id3_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/i/id3/id3_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('39a96bcac200680d59d78496d0e40699f73ad890b1077d2e33732492a2b5d2a8bc3ee24eae8740c6915cd28409fa3ba8e154811e473c72b121c4e9e7a9fb27d3'
            'e75d436b37c22b4e0196b7d3e493de6542d7e6d12cba1b6977c838ae58a8e09fa484eb055784eaf52acaaa7e3e103fa7b1094b2d17198e9283c7dea093603b29')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make prefix="${pkgdir}/usr" mandir="${pkgdir}/usr/share/man" install

  # install license
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}