# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=icon-naming-utils
pkgver=0.8.90
pkgrel=1
pkgdesc="Maps the new names of icons to their legacy counterparts"
arch=('any')
license=('GPL-2')
depends=('perl-xml-simple')
source=("https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.sig}
        "remove-legacy-calc.patch")
sha512sums=('6c23f6138e053f9fc6de9d56f94b80849f29f9fde46cdf54b705720cb48b0c660f315484fb36fb9936d4ceade7768aad2d17280545a4b392aa56185c9452999d'
            'SKIP'
            'a29df0d7acbbb72c46adaf857ae054b10c4422562e3ba1b626368a6be2be244e80eef65deede392164ef296af7c08a08753f6d3c5e33a5d35acc4586b67cc080')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/remove-legacy-calc.patch"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  mkdir -p "$pkgdir/usr/lib/"
  mv "$pkgdir/usr/share/pkgconfig" "$pkgdir/usr/lib/pkgconfig"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}