# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=i3-wm
_pkgsourcename=i3
pkgver=4.22
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Improved dynamic tiling window manager"
arch=('i686' 'x86_64')
url='https://i3wm.org/'
license=('Modified-BSD')
replaces=('i3' 'i3bar')
groups=('i3')
backup=('etc/i3/config')
depends=('libev' 'libxkbcommon-x11' 'pango' 'startup-notification'
         'xcb-util-cursor' 'xcb-util-keysyms' 'xcb-util-wm' 'xcb-util-xrm'
         'yajl' 'pcre2')
makedepends=('meson' 'xmlto' 'quilt')
optdepends=('dmenu: for the default program launcher'
            'rofi: for a modern dmenu replacement'
            'slock: for the default screen locker'
            'i3status: for the default status bar generator'
            'perl: for i3-save-tree and i3-dmenu-desktop'
            'perl-anyevent-i3: for i3-save-tree'
            'perl-json-xs: for i3-save-tree')
source=("https://i3wm.org/downloads/${_pkgsourcename}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/i/i3-wm/i3-wm_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('4e4536fb4108e92a1c918b5869232c0f7eb0feca2d3a49ba87250b970df0614cfe256d1e41fbd825a81c43b82898651e5d3fc11ca8101978916754dfa885266a'
            '2b9626569478e84c4e33abec9f7c464dfdd253bcd0484a6cb0cdb11cd8e5276f773b3d42ae54dd9ee48a4304da8402e344d6533a1e500f47f2332b2001df9672')

prepare() {
  cd "$srcdir/$_pkgsourcename-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd i3-$pkgver
  hyperbola-meson build
  ninja -C build
}

package() {
  cd i3-$pkgver
  DESTDIR="$pkgdir" ninja -C build install
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}