# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=hwloc
pkgver=2.3.0
_debver=2.3.0+dfsg
_debrel=2
pkgrel=1
pkgdesc='Portable Hardware Locality is a portable abstraction of hierarchical architectures'
url='https://www.open-mpi.org/projects/hwloc/'
arch=('i686' 'x86_64')
license=('Modified-BSD')
depends=('libtool' 'libpciaccess')
makedepends=('libxml2' 'pciutils' 'quilt')
optdepends=('libxml2' 'pciutils')
options=('!docs')
source=(https://www.open-mpi.org/software/hwloc/v${pkgver%.*}/downloads/${pkgname}-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/h/hwloc/hwloc_$_debver-$_debrel.debian.tar.xz)
sha512sums=('ecb0950cd08eab7d97f7cbef9db0dc31cb5b4debedaae6f48814625ee5da0153fdc1f863fa84c5d59b76634e877a348fa556f3c8c29fc43bc6ae7211c313906c'
            'a2875838a85920d9598d13c3144aa5309c931b16b9748555b29ca7fe35c9bf7eda4468b5bf7f3883c351bed16140acd95105ffdeb0afc47494056cac583a47a5')

prepare() {
  cd hwloc-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -fiv
}

build() {
  cd hwloc-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-cairo \
    --enable-plugins \
    --sysconfdir=/etc
  make
}

check() {
  cd hwloc-${pkgver}
  make check
}

package() {
  cd hwloc-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: