# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=htop
pkgver=3.4.0
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Interactive process viewer"
arch=('i686' 'x86_64')
url='https://htop.dev/'
license=('GPL-2')
depends=('ncurses' 'libnl')
makedepends=('quilt')
optdepends=('lsof: show files opened by a process'
            'strace: attach to a running process')
options=('!emptydirs')
source=("https://github.com/htop-dev/htop/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/htop/htop_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('aff7fc1961687b885fe680ec27cd08fdfdcc8b5411156fa7195e7acce10b7cf3c11eca7d6f55741da2d286ade77a0238f609cfeb862151cdaf6815087c73c340'
            'b4b3b60d697b5cd27f234d3395e8295e9475c780196f1820315e9f7565974344a3641b1519c6f63311dbbdd85b489c250498b662dae2b4b12a7601c54437b2aa')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -fi
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-affinity \
    --enable-capabilities \
    --enable-delayacct \
    --enable-openvz \
    --enable-unicode \
    --enable-vserver

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}