# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=hsetroot
pkgver=1.0.2
_debver=$pkgver
_debrel=9
pkgrel=1
pkgdesc="Tool which allows you to compose wallpapers ('root pixmaps') for X"
url='https://directory.fsf.org/wiki/Hsetroot'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('imlib2')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/h/hsetroot/hsetroot_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/hsetroot/hsetroot_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('cac98cc602fd8825dbfce27d289dc4ba47805c99c78de804e95c539e83ffae6984601a535cdb90658536a007a5f17c71e27e4c31af562ade6610f11f0d0d2ca5'
            'd23ced51a973e74e12f4d65bf096013a53ed5269aa89d6ce1776526859c2d4176a110a8314dbd87c0e9a6e92557409f30b3911c12efc909967401609888b368c')

prepare() {
  mv $pkgname-$pkgver.orig $pkgname-$pkgver
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  LDFLAGS+=",--no-as-needed,-lX11" ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}