# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=herbe
pkgver=1.0.0
pkgrel=1
epoch=1
pkgdesc='Daemon-less notifications, minimal and lightweight.'
arch=('i686' 'x86_64')
url='https://github.com/dudik/herbe'
license=('Expat' 'Public-Domain')
depends=('libx11' 'libxft')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/dudik/${pkgname}/archive/${pkgver}.tar.gz"
        "notify-send")
sha512sums=('3f49de25fd92194d1354054c207616343d9c21a9d82c6c4e3316ebc5228c0bd90650621438d14cd4730135f328c0438ef054a2b6843f3bd4d15f9cb47a22df12'
            'bc6f21bf1e483a9b73bc13a57505c2b964528b30fe02f45c68b57570e3b838fb04e77d407e5b947fa76954f49098bd4dcf6b951c66ba57938ac93eb0c185771d')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # handling binaries
  install -d -m0755 "${pkgdir}/usr/bin"
  mv "${pkgdir}/usr/local/bin/herbe" "${pkgdir}/usr/bin/herbe"
  rm -rf "${pkgdir}/usr/local/"
  cp "${srcdir}/notify-send" "${pkgdir}/usr/bin/"
  chmod +x "${pkgdir}/usr/bin/notify-send"

  # license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}