# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gtypist
pkgver=2.9.5
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="Free, libre and simple ncurses touch typing tutor"
arch=('i686' 'x86_64')
url='http://www.gnu.org/software/gtypist/gtypist.html'
license=('GPL-3')
depends=('ncurses' 'perl')
makedepends=('quilt')
source=("https://ftp.gnu.org/gnu/gtypist/${pkgname}-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gtypist/gtypist_${_debver}-${_debrel}.debian.tar.xz"
	"fix-ncurses.patch")
sha512sums=('ea8db72e83a41340a4435e2802134a852fb61eb00f10267733455491fc9ce3356f61887146de21ec589a77ea1169ad5b75a0eba1708566b7327f4801bd6dcb52'
            'ae995eb314deffdac7f175ee7c13001be31a1e2f2eb93ad3368c11212755c8eb87bc5c6e9c6d91a4360370173fe5b814a4147cf5b1a13fd1f98ba41e2f128306'
            '0c2dcebb2a45dc23ec795bf9bbd4841bbaa69662dc6897a6f73989548e4a626e261780a593b5f938df9b3b1451edcf96daac8b693274675ca27e3d18bf18764e')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  patch -p1 <"$srcdir"/fix-ncurses.patch
  autoreconf
}

build() {
  cd "$srcdir"/$pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make prefix="$pkgdir"/usr install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}