# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gtkspell3
pkgver=3.0.9
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="Provides word-processor-style highlighting and replacement of misspelled words in a GtkTextView widget"
arch=('i686' 'x86_64')
url='http://gtkspell.sourceforge.net/'
license=('GPL-2')
depends=('gtk' 'enchant')
makedepends=('intltool' 'gobject-introspection' 'vala' 'tauthon' 'mesa-libgl' 'quilt')
source=("https://downloads.sourceforge.net/gtkspell/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/gtkspell3/gtkspell3_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('de6cc24ca092067a101996142bf2b3cfb6a5af2170ea4b0185a997e5c88adead7ba53c5a297c3110b3a66dc87d37e429720f972895bb2931f9a033fc006e2eab'
            'c6dad95ff2a2e06ecf9188064913fc6ebb71205511a0ead60c7491db3704dd73c61f5eed7a2537903709140bf1f7a41c4abb7146242ade23fd66ac85dd4953be')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # remove gtk-doc
  rm -rf "$pkgdir/usr/share/gtk-doc"

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}