# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gtkmm
pkgver=3.24.2
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="C++ bindings for GTK"
url='https://www.gtkmm.org/'
arch=('i686' 'x86_64')
license=('LGPL-2.1' 'GPL-2')
depends=('gtk' 'pangomm' 'atkmm')
makedepends=('mm-common' 'glibmm' 'cairomm' 'pangomm' 'quilt')
source=("https://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/${pkgname}3.0/${pkgname}3.0_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c8f9f03d54006a729fdad7563d3be37aa180f9153c222314c1b8cfddc5ab417d184422a1d44f780574248ea52e679f1e360eac67e03f67d29ecf847c0ab19689'
            'b415145cf7c7e40cbd3ee74b9df89208e300c6f95c91f9e05998beb84b8b509682e144dcd35fe3449f6942e116a3258081b1cb303d01beeb0b5b783d72032f38')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-maintainer-mode
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
  make DESTDIR="$pkgdir" install
  make -C docs DESTDIR="$pkgdir" install
  install -Dm644 COPYING COPYING.tools -t $pkgdir/usr/share/licenses/$pkgname
}