# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gtkmathview
pkgver=0.8.0
_debver=$pkgver
_debrel=15
pkgrel=2
pkgdesc="C++ rendering engine for MathML documents"
arch=('i686' 'x86_64')
url='http://helm.cs.unibo.it/mml-widget/'
license=('LGPL-3')
depends=('popt' 'libxml2' 'glib2')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/g/gtkmathview/gtkmathview_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gtkmathview/gtkmathview_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('59e7452905c857b9e251a9bb9ed6a0e3cf61e807769b0933cfa8f669e436c01f2e6d73a34ea7bcd74f3b2ca7cf25eee768bee1b6bd2d6d5fcd89194885fef796'
            'f74aeb8f88465fe02adbf5fc02543ac5085c30d70793c4ae707aaf61d1de9a01918e8129519d86491492494ff8541ef7f687f6a2db1d17cf5e104c82f2e51f6c')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # AM_BINRELOC missing, just ignore
  echo 'AC_DEFUN([AM_BINRELOC], [])' > acinclude.m4
  autoreconf -if
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --disable-static \
    --disable-gtk \
    --disable-gmetadom
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}/" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}