# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gtkglext
pkgver=1.2.0
_debver=$pkgver
_debrel=9
pkgrel=2
pkgdesc="OpenGL extensions for GTK+ 2.x"
arch=('i686' 'x86_64')
url="http://gtkglext.sourceforge.net/"
license=('LGPL-2.1')
depends=('gtk2' 'glu' 'libxmu' 'pangox-compat')
makedepends=('python' 'quilt')
source=("https://downloads.sourceforge.net/sourceforge/gtkglext/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/g/gtkglext/gtkglext_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c5452b7594195da3c1428dc3021a041d70bb8079a514b7310fe7b66f638748ad2399adead36047b52b60b033757581e72f0532c0301e033019bf909f7365071d'
            'c29590301faad97af7451b2916d9220ac685798d269866e9da055f8da986bd19077ca6e5dc9d1975caf46510a56708b0adfba9699d47abe0bf99ee4fdcfa8112')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vi
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr \
              --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/share/gtk-doc
  install -Dm644 COPYING.LIB -t "${pkgdir}"/usr/share/licenses/$pkgname
}