# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gstreamermm
pkgver=1.10.0
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="C++ interface for GStreamer"
arch=('i686' 'x86_64')
url='https://gstreamer.freedesktop.org/bindings/cplusplus.html'
license=('LGPL-2.1' 'GPL-2')
depends=('glibmm' 'gst-plugins-base')
makedepends=('mm-common' 'cairomm' 'pangomm' 'quilt')
source=("https://ftp.gnome.org/pub/GNOME/sources/gstreamermm/1.10/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/gstreamermm-1.0/gstreamermm-1.0_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('34eeb9eec5958c96acf7c7791eef80138e5d55fea6ddf1bf9ace6b1ec7f052da2abf04d87089e4c9ead51c631ef7afceaf9fceb946ec3d105da522187c69e429'
            '9aea75b5022fed90d5e20ce3f5bec009486cacd0b129cf4ee5e388ee7e24a90039908e3823bf3e493b3d452847152fc877a88f298d2b099ccf2d6f02ec26da9d')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-maintainer-mode
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
  make DESTDIR="$pkgdir" install
  make -C docs DESTDIR="$pkgdir" install
  install -Dm644 COPYING{,.tools} -t "${pkgdir}/usr/share/licenses/$pkgname"
}