# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gstreamer
pkgver=1.18.3
_debver=1.18.3
_debrel=1
pkgrel=1
pkgdesc="Multimedia graph framework - core"
url="https://gstreamer.freedesktop.org/"
arch=(i686 x86_64)
license=(LGPL-2)
depends=(libxml2 glib2 libunwind libcap libelf python)
makedepends=(gobject-introspection bash-completion meson gmp gsl gtk quilt)
install=gstreamer.install
source=(https://gstreamer.freedesktop.org/src/$pkgname/$pkgname-$pkgver.tar.xz
        https://deb.debian.org/debian/pool/main/g/gstreamer1.0/gstreamer1.0_$_debver-$_debrel.debian.tar.xz
        byacc.patch)
sha512sums=('c0258fb1f233facec72b5004d33d36871b11235d369e7f1f1e0597c5880bef89a5337550fa8b285688b5c9f42dac6e7d1f1208076d4b90a09363d2805e0dfba9'
            '6d296df98d9e798741196c0880d787cc512777c000da855844fe68e32fa8cae0fabbd0a14d9288823e91edafab7cb5b427caf84ba9c9a27926e21b33c00b57b5'
            '3b6dcee15ea2d04d49131b9d9bb9252563513ed60f2b2222a10af2deb17df7b0966165d59532e2a7a1a05d1f01d700380c6463f187ce725f2872c7c39e612ac2')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/0001-registrybinary-Update-magic-version-string.patch || true

    quilt push -av
  fi
  patch -p1 -i ../byacc.patch
}

build() {
  hyperbola-meson $pkgname-$pkgver build \
    -D doc=disabled \
    -D ptp-helper-permissions=none \
    -D dbghelp=disabled \
    -D gobject-cast-checks=disabled \
    -D package-name="GStreamer (Hyperbola GNU/Linux-libre)" \
    -D package-origin="https://www.hyperbola.info/"
  meson compile -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 $pkgname-$pkgver/COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}