# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gst-libav
pkgver=1.18.4
pkgrel=1
pkgdesc="Multimedia graph framework - libav plugin"
url="https://gstreamer.freedesktop.org/"
arch=(i686 x86_64)
license=('LGPL-2' 'LGPL-2.1')
depends=(gst-plugins-base-libs bzip2 ffmpeg)
makedepends=(python meson)
provides=("gst-ffmpeg=$pkgver-$pkgrel")
source=("https://gstreamer.freedesktop.org/src/$pkgname/$pkgname-$pkgver.tar.xz")
sha512sums=('4eb10af6698f724bbc8d5b7b215e7349e6ff3b52e24b3987ee4077db1ae27ae0d6f25309adc50f0fccdf5af4d617634a7339ad1e5466a737c40a25c52c0d023f')

prepare() {
  cd $pkgname-$pkgver
}

build() {
  cd $pkgname-$pkgver
  hyperbola-meson build \
    -D doc=disabled \
    -D package-name="GStreamer FFmpeg Plugin (Hyperbola GNU/Linux-libre)" \
    -D package-origin="https://www.hyperbola.info/"
  meson compile -C build
}

check() {
  cd $pkgname-$pkgver
  meson test -C build --print-errorlogs
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}