# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gphotofs
pkgver=0.5
_debver=0.5
_debrel=6
pkgrel=1
pkgdesc='FUSE filesystem module to mount your camera as a filesystem on GNU/Linux.'
arch=('i686' 'x86_64')
url='http://www.gphoto.org/proj/gphotofs/'
license=('GPL-2')
depends=('fuse2' 'glib2' 'libgphoto2')
makedepends=('pkgconfig')
source=(http://downloads.sourceforge.net/sourceforge/gphoto/gphotofs-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/g/gphotofs/gphotofs_$_debver-$_debrel.debian.tar.xz)
sha512sums=('6f5bcaf8ca820c0590ec95af55ec9438c864a298660ad15c6d6e8f59201a7f873d29f16cf77d13538111f6cec3f958ea0ac88c6c51836ab2d8c9d6cca156ed3a'
            '222c664587e7874446729b1435bb56ace80db7a211ace6366ecc661f2311e720b59f01526fd10b6f4b388795a5c3c5c60937ff2a97a60d11bd60a8b47f67ef07')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}