# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gperf
pkgver=3.1
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="Perfect hash function generator"
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/gperf/'
license=('GPL-3')
depends=('gcc-libs' 'texinfo')
makedepends=('quilt')
options=('!makeflags')
source=("https://ftp.gnu.org/pub/gnu/gperf/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gperf/gperf_$_debver-$_debrel.debian.tar.xz")
sha512sums=('855ebce5ff36753238a44f14c95be7afdc3990b085960345ca2caf1a2db884f7db74d406ce9eec2f4a52abb8a063d4ed000a36b317c9a353ef4e25e2cca9a3f4'
            'a76ce58c1263e321b805f5ea5e0cbc93f20ac28e88439cfec0c23eca865d49ebdcec85291ab5dc987437d2b4a9e8432fa61c9ba308151b6528f809b40ee71c6e')

prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --docdir=/usr/share/gperf/doc/
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}