# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gparted
pkgver=1.5.0
pkgrel=2
pkgdesc="A lightweight frontend to GNU Parted"
arch=('i686' 'x86_64')
url='https://gparted.org/'
license=('GPL-2' 'FDL-1.2' 'FDL-1.3' 'Modified-BSD')
depends=('parted' 'gtkmm')
makedepends=('intltool' 'itstool' 'pkg-config' 'yelp-tools' 'gettext-tiny')
optdepends=('dosfstools: for FAT16 and FAT32 partitions'
            'jfsutils: for jfs partitions'
            'f2fs-tools: for Flash-Friendly File System'
            'btrfs-progs: for btrfs partitions'
            'exfatprogs: for exFAT partitions'
            'ntfs-3g: for ntfs partitions'
            'reiserfsprogs: for reiser partitions'
            'xfsprogs: for xfs partitions'
            'nilfs-utils: for nilfs2 support'
            'gpart: for recovering corrupt partition tables'
            'mtools: utilities to access MS-DOS disks'
            'xenocara-xhost: authorization from X11')
source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "copyright::https://metadata.ftp-master.debian.org/changelogs//main/g/gparted/gparted_${pkgver}-1_copyright")
sha512sums=('af32358bc470d30c38cdf688e8f940548c7361808fbc7712dc79ef6d196e3bfbf9c9e0ee499729e78d4b782ed1f52ea1f55c983e9afe8fc3fea765078ffbddad'
            'e7efea820b7523fb46d662905a6a1ccb32cefca6665db7c67640459da61396bb6512f49ca12ec254c948d4eba645a17efbe97ca109b4152bd6ed4106882e1141')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/libexec/gparted \
    --disable-online-resize \
    --enable-libparted-dmraid \
    --enable-xhost-root
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING ${srcdir}/copyright -t $pkgdir/usr/share/licenses/$pkgname
}