# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gpa
pkgver=0.10.0
_debver=$pkgver
_debrel=5
pkgrel=2
pkgdesc="A graphical user interface for the GnuPG"
arch=('i686' 'x86_64')
url='https://www.gnupg.org/related_software/gpa/'
license=('GPL-3' 'LGPL-3')
depends=('gpgme' 'gtk2')
makedepends=('quilt')
source=("https://gnupg.org/ftp/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/g/gpa/gpa_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('87004fb0806e76012bc194f95afe9ef6044aec890b26e845f45c314e1bd8864f056ba5e32f9ef2e15b24b50840235e6e548a5e3006b255b4f1c20e0fd7710a3b'
            '3939cfd222ca809ee508aecb7df0a22e18648ac2dcc7f2b6b451e6dc897f67c5dd02f63945792d905b86c24c41bcba2bbb2164189358a71a86b12087b30fdccf')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir/" install
  install -Dm644 {AUTHORS,ChangeLog,NEWS,README,THANKS,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}